SAMPLE 1 20
READ(FIRM1.txt) YEAR IGM FGM CGM ICHR FCHR CCHR / SKIPLINES=1
READ(FIRM2.txt) YEAR IGE FGE CGE IWH FWH CWH / SKIPLINES=1
READ(FIRM3.txt) YEAR IUS FUS CUS  / SKIPLINES=1
* Stack the data
MATRIX I=(IGM'|ICHR'|IGE'|IWH'|IUS')'
MATRIX F=(FGM'|FCHR'|FGE'|FWH'|FUS')'
MATRIX C=(CGM'|CCHR'|CGE'|CWH'|CUS')'

GEN1 NC=5
GEN1 NT=20    
* Create cross-section dummy variables.
MATRIX CSDUM=SEAS(100,-NC)

* OLS estimation with dummy variables
SAMPLE 1 100
POOL I F C CSDUM / NOCONSTANT NCROSS=5 OLS HETCOV RSTAT RESID=E

* Compute a p-value for the Durbin-Watson statistic
GEN1 K=$K
GEN1 NOBS=100
MATRIX X=(F|C|CSDUM)
MATRIX M=IDEN(NOBS)-X*INV(X'X)*X'
* Generate the A matrix
SAMPLE 1 NT
GENR D=2
IF(TIME(0).EQ.1) D=1
IF(TIME(0).EQ.NT) D=1
MATRIX A=IDEN(NT,2)
MATRIX A=-(A+A')+DIAG(D)
MATRIX ASTAR=IDEN(NC)@A
* Get the eigenvalues of MA (sorted in descending order)
MATRIX MA=M*ASTAR
MATRIX EDW=EIGVAL(MA)
* Determine the number of non-zero eigenvalues.
GEN1 DF=NOBS-K
* Compute the DW statistic
MATRIX DWTEST=(E'ASTAR*E)/(E'E)
* Compute the p-value with the IMHOF routine.
SAMPLE 1 1
DISTRIB DWTEST / EIGENVAL=EDW TYPE=IMHOF NEIGEN=DF CDF=PVALUE
PRINT DWTEST DF PVALUE
STOP