SAMPLE 1 20
READ(FIRM1.txt) YEAR IGM FGM CGM ICHR FCHR CCHR / SKIPLINES=1
READ(FIRM2.txt) YEAR IGE FGE CGE IWH FWH CWH / SKIPLINES=1
READ(FIRM3.txt) YEAR IUS FUS CUS  / SKIPLINES=1
* Stack the data
MATRIX I=(IGM'|ICHR'|IGE'|IWH'|IUS')'
MATRIX F=(FGM'|FCHR'|FGE'|FWH'|FUS')'
MATRIX C=(CGM'|CCHR'|CGE'|CWH'|CUS')'

SAMPLE 1 100
* Pooling by OLS  
POOL I F C / NCROSS=5 OLS DN
* Pooling by OLS with Panel-Corrected Covariance Matrix
POOL I F C / NCROSS=5 OLS HETCOV 

* Generate a cross-section index
*  Set the number of time periods
GEN1 NT=20
GENR CSINDEX=SUM(SEAS(NT))
* Get standard errors with correction for heteroskedasiticity but
* assume the restriction of no cross-section correlation.
POOL I F C / NCROSS=5 OLS HETCOV CSINDEX=CSINDEX

* Now get the White standard errors
OLS I F C / HETCOV

* Create cross-section dummy variables.
*  Set the number of cross-sections
GEN1 NC=5
MATRIX CSDUM=SEAS(100,-NC)
DO #=1,NC
 GENR D#=CSDUM:#
ENDO

* OLS estimation with dummy variables
POOL I F C D1-D5 / NOCONSTANT NCROSS=5 OLS HETCOV RSTAT
* Test for equality of firm intercepts
TEST
  TEST D1=D2
  TEST D1=D3
  TEST D1=D4
  TEST D1=D5
END
STOP