* Heteroskedasticity in OLS Model for R&D Expenditure
*
* Keywords:
*     regression, ols, linear, heteroskedasticity, park, glejser, white, test,
*     errors, graph, r&d, expenditure, sales, profits
*
* Description:
*     We illustrate how to estimate a linear OLS Model for R&D Expenditure, use
*     Park, Glejser and White's Heteroskedasticity Tests, use White's Standard
*     Errors and graph residuals
*
* Author(s):
*     Skif Pankov
*
* Source:
*    Damodar N. Gujarati and Dawn C. Porter, Basic Econometrics - 5th Edition
*    McGraw-Hill International Edition, Chapter 11, Example 11.10 (page 397)
*
sample 1 14

* Reading the datafile and naming variables
read(data_11.10.shd) sale rd prof

* Running an OLS regression of rd on sale, specifying to save residuals in
* a variable rds
ols rd sale / resid = reds

* Conducting heteroskedasticity tests on the regression just estimated
diagnos / het

* Generating the squares and absolute values of the residuals and a
* square of sales for explict demostration of Park's, Glejser's and White's
* heteroskedasticity tests
genr u2 = reds**2
genr ua = abs(reds)
genr sale2 = sale**2

* Running a regression for Park's test
ols u2 sale

* Running a regression for Glejser's test
ols ua sale

* Running a regression for White's test
ols u2 sale sale2

* Runnig the first OLS regression, specifying to use White's standard
* errors
ols rd sale / hetcov

* Generating graphs of residuals and square residuals
graph reds
graph u2

stop