* Autocorrelation Induced by Misspecification in Gasoline Market Model
*
* Keywords:
*     regression, ols, autocorrelation, misspecification, gasoline, market, us,
*     graph
*
* Description:
*     We address the issue of autocorrelation in the US Gasoline Market by 
*     adjusting the model we are estimating
*
* Author(s):
*     Noel Roy
*     Skif Pankov
*
* Source:
*    William H. Greene, Econometric Analysis - 7th Edition
*    Pearson International Edition, Chapter 20, Example 20.2 (page 943)
*
time 1953.0 1
sample 1953.0 2004.0

* Reading the data and naming variables, specifying to ignore the first 
* line
read (TableF2-2.shd) year,gasexp,pop,gasp,income,pnc,puc,ppt,pd,pn,ps &
/skiplines=1 

* Genearing variables
genr lgpop = log(gasexp/pop/gasp)
genr lpg = log(gasp)
* (a) Regression on log pg
?ols lgpop lpg /graph
genr lny = log(income)
* (b) Regression of log pg, log i/pop
?ols lgpop lpg lny /graph
* (c) Full regression
genr lpnc = log(pnc)
genr lpuc = log(puc)
genr lppt = log(ppt)
genr lpn = log(pn)
genr lpd = log(pd)
genr lps = log(ps)
?ols lgpop lpg lny lpnc lpuc lppt lpn lpd lps year /graph

* (d) Full regression, separate coefficients break up the sample by setting 
* dummy variables for 1975-95.
genr per2=dum(year-1974)
genr lpg2=lpg*per2
genr lny2=lny*per2
genr lpnc2=lpnc*per2
genr lpuc2=lpuc*per2
genr lppt2=lppt*per2
genr lpn2=lpn*per2
genr lpd2=lpd*per2
genr lps2=lps*per2
genr year2=year*per2
?ols lgpop lpg lny lpnc lpuc lppt lpn lpd lps year per2 lpg2 lny2 lpnc2 &
	lpuc2 lppt2 lpn2 lpd2 lps2 year2 /graph

stop