SAMPLE 1 40
READ (GHJ.txt) FOOD INCOME / CLOSE
* Run an OLS regression and save the coefficients in the variable BETA.
OLS FOOD INCOME / COEF=BETA
* Get the standard error
GEN1 SIG=SQRT($SIG2)
* Set the number of replications for the Monte Carlo experiment.
GEN1 NREP=1000
SET RANFIX NODOECHO NOOUTPUT
DIM B40 NREP
* Use a DO-loop to do repeat operations
DO #=1,NREP
* Generate random normal numbers with standard deviation SIG.
  GENR E=NOR(SIG)
* Generate Y
  GENR Y = BETA:2 + BETA:1 * INCOME + E
* Run an OLS regression and save the estimated coefficients.
  OLS Y INCOME / COEF=BTEMP
  GEN1 B40:#=BTEMP:1
ENDO
DELETE FOOD INCOME E Y 

* Now duplicate the observations and repeat the Monte Carlo experiment.
SAMPLE 41 80
READ (GHJ.txt) FOOD INCOME / CLOSE
SAMPLE 1 40
READ (GHJ.txt) FOOD INCOME / CLOSE
SAMPLE 1 80
DIM B80 NREP
DO #=1,NREP
  GENR E=NOR(SIG)
  GENR Y = BETA:2 + BETA:1 * INCOME + E
  OLS Y INCOME / COEF=BTEMP
  GEN1 B80:#=BTEMP:1
ENDO
SET OUTPUT
* Analyze the results - a histogram gives a frequency distribution.
SAMPLE 1 NREP
STAT B40 B80
PLOT B40 / HISTO GROUPS=30
PLOT B80 / HISTO GROUPS=30
STOP