*   R. Carter Hill, William E. Griffiths and Guay C. Lim,  
*   Principles of Econometrics, Third Edition, Wiley, 2008.

* Chapter 7  A Wage Equation
      
SAMPLE 1 1000
READ (cps_small.shd) wage educ exper female black white midwest south west

STAT wage educ exper / MEDIAN=median
PRINT median

* Chapter 7.1.2  Polynomials in a Wage Equation
GENR exper2=exper**2
OLS wage educ exper exper2 / COEF=b
* Estimate the turning point (top of page 170)
TEST -exper/(2*exper2)
* The temporary variable $VAL stores the estimate.
GEN1 peak=$VAL
PRINT peak

* Estimate the marginal effect of experience at the sample median
* (bottom of page 169)
GEN1 meffect=(b:2) + 2*(b:3)*median:3
PRINT meffect

* Chapter 7.3  Applying Dummy Variables
GENR blfem=black*female
* Wage Equation - Table 7.4, page 176 
OLS wage educ black female blfem
* F-test page 177
TEST
 TEST black=0
 TEST female=0
 TEST blfem=0
END

* Wage Equation - Table 7.5, page 178
OLS wage educ black female blfem south midwest west
* Test the null hypothesis of no regional differences (top of page 179).
TEST
 TEST south=0
 TEST midwest=0
 TEST west=0
END

* Chapter 7.3.3  The Chow Test
* Test for differences between the wage regressions for the south
* and the rest of the country.
*  Create interaction variables
GENR south1=educ*south 
GENR south2=black*south 
GENR south3=female*south 
GENR south4=blfem*south 
*  Model estimation  Column (1) Table 7.6, page 180.
OLS wage educ black female blfem south south1-south4
*  Get coefficient estimates for workers in the south
*  Column (3) Table 7.6, page 180.
*  Note: the standard errors are calculated using the error variance 
*  estimate for the full model.
TEST constant+south
TEST educ+south1
TEST black+south2
TEST female+south3
TEST blfem+south4
*  The F-test (Chow test) statistic, page 181.
TEST
 TEST south=0
 TEST south1=0
 TEST south2=0
 TEST south3=0
 TEST south4=0
END

* Now estimate a separate wage equation for southern workers.
* This replicates the standard errors reported in 
* Column (3) Table 7.6, page 180.
SET NOWARNSKIP
SKIPIF (south.EQ.0)
OLS wage educ black female blfem
DELETE SKIP$
STOP