* Specification Tests in a Labour Force Participation Model
*
* Keywords:
*     probability, probit, chow, lm, wald, likelihood ratio, female, labour, supply
*
* Description:
*     We estimate a Probit model for female labour force participation and
*     test the significance of estimated coefficients
*
* Author(s):
*     Noel Roy
*     Skif Pankov
*
* Source:
*    William H. Greene, Econometric Analysis - 7th Edition
*    Pearson International Edition, Chapter 17, Example 17.10 (page 755)
*
sample 1 753

* Reading the datafile and naming the variables, specifying to ignore the
* first 37 lines of the file
read (TableF5-1.shd) lfp whrs kl6 k618 age educatn wwrpwg hhrs ha he hw & 
income / skiplines=1

* Generating regression variables
genr age2=age**2
genr kids=dum(kl6+k618)

* Restricted model:
* Estimating the probit model in table 17.7 under the null hypothesis of 
* Homoskedasticity, specifying to save estimated coefficients, index function
* and inverse mills ratio
probit lfp age age2 income educatn kids / coef=b index=xb imr=lambda

* Saving the log of the likelihood function for likelihood ratio testing
gen1 llfr=$llf

* Testing whether the equation is the same for kids=1 and kids=0
set nowarnskip

* kids=1
skipif (kids)
?probit lfp age age2 income educatn 
gen1 llfu1=$llf
delete skip$

* kids=0
skipif (1-kids)
?probit lfp age age2 income educatn 
gen1 llfu2=$llf
delete skip$

* lr test
gen1 lr=2*(llfu1+llfu2-llfr)
distrib lr / type=chi df=5

* Unrestricted model (Heteroskedasticity)
*
* Estimaitng probit model with heteroskedastic disturbances can be estimated 
* using the nl command with the logden option
*
* Defining a maximum number of characters in a command line
set comlen=255
term: (b1*age+b2*age2+b3*income+b4*educatn+b5*kids+b6)/exp( &
gamma1*kids+gamma2*income)

* Setting up the log-likelihood function for the probit model with Heteroscedasticity 
* using the nl command. The starting values for 
* the parameter estimates are set to the estimates from the probit model 
* which assumes no heteroscedasticity (i.e. gamma=0)
dim bhet 8
copy b bhet / frows=1;6 trows=1;6
set nowarn
nl 1 / logden ncoef=8 genrvar start=bhet conv=.0000001 cov=v
   eq lfp*log(ncdf([term]))+(1-lfp)*log(1-ncdf([term]))
end 

* Likelihood ratio test of the null hypothesis of homoskedasticity
gen1 lr=2*($llf-llfr)
print lr 

* LM test 
* Calculating the variables gi xi. in the probit model, gi = lambda_i
* which has been saved by the probit /img= option.
genr one=1
genr l1=lambda*age
genr l2=lambda*age2
genr l3=lambda*income
genr l4=lambda*educatn
genr l5=lambda*kids

* Calculating the derivatives of the log-likelihood with respect to the gamma_i
* parameters
genr l6=-lambda*xb*kids
genr l7=-lambda*xb*income
copy lambda l1-l7 gx

* Calculating the LM statistic, using the bhhh estimator for the covariance
* matrix.
matrix lm=one'gx*inv(gx'gx)*gx'one
print lm

* Calculating the wald test
matrix vm=v(7;8,7;8)
matrix bm=gamma1|gamma2
matrix w=bm*inv(vm)*bm'
print w

* Taking the significance levels
distrib lr lm w / type=chi df=2

stop